bom拆分（半成品折算成材料）

lucky8830000

各位老师好！

抱歉又来讨教了！

请看附件。一台车由很多材料和半成品组成。我要的数据是，要求把所有半成品折算成材料，同时也需要所对应耗用的材料数量。

感谢老师！

私信q_924154615

你漏了附件

lucky8830000

私信q_924154615 发表于 2020-8-1 14:27
你漏了附件

已经更新了。感谢老师提醒！

私信q_924154615

看不懂，左边如何整成右表的？
同时你左表就4个自行车整成，右表就那么多整车
而且如左表辐条36，右表如何变成的72？
规则能不能说的明确有点，需求明确一点
哪怕口述一遍  如果如果  是如何操作的

lucky8830000

这个是不是无法解决呢..可以提示一下吗，各位老师。

一把小刀闯天下

'有点问题修改了一下，感谢wodewan 老师的提醒，，，

'--------------------------

Option Explicit

Sub test()
  Dim arr, dic(2), i, j, m, key, t
  For i = 0 To UBound(dic)
    Set dic(i) = CreateObject("scripting.dictionary")
  Next
  arr = Range("a3:c" & Cells(Rows.Count, "a").End(xlUp).Row).Value
  ReDim brr(1 To 10 ^ 4, 1 To 3)
  For i = 1 To UBound(arr, 1)
    dic(2)(arr(i, 2)) = arr(i, 3)
  Next
  For i = 1 To UBound(arr, 1)
    If dic(2).exists(arr(i, 1)) Then
      dic(1)(arr(i, 1)) = dic(1)(arr(i, 1)) & Space(1) & arr(i, 2)
    Else
      dic(0)(arr(i, 1)) = dic(0)(arr(i, 1)) & Space(1) & arr(i, 2)
    End If
  Next
  For Each key In dic(0).keys
    t = Split(dic(0)(key))
    For i = 1 To UBound(t)
      If dic(1).exists(t(i)) Then
        Call dfs(dic, key, t(i), brr, m, dic(2)(t(i)))
      Else
        m = m + 1
        brr(m, 1) = key: brr(m, 2) = t(i): brr(m, 3) = dic(2)(t(i))
      End If
    Next
  Next
  [j3].Resize(UBound(brr, 1), UBound(brr, 2)) = brr
End Sub

Function dfs(dic, key, s, brr, m, sum)
  Dim i, t, lastvalue
  t = Split(dic(1)(s))
  For i = 1 To UBound(t)
    If dic(1).exists(t(i)) Then
      lastvalue = sum
      Call dfs(dic, key, t(i), brr, m, sum * dic(2)(t(i)))
      sum = lastvalue
    Else
      m = m + 1
      brr(m, 1) = key: brr(m, 2) = t(i): brr(m, 3) = sum * dic(2)(t(i))
    End If
  Next
End Function

lucky8830000

私信q_924154615 发表于 2020-8-1 14:45
看不懂，左边如何整成右表的？
同时你左表就4个自行车整成，右表就那么多整车
而且如左表辐条36，右表如 ...

这个道理很简单的。一辆车要2个轮子，每个轮子需要36根辐条钢线。所以一辆车需要72根辐条。

lucky8830000

一把小刀闯天下 发表于 2020-8-1 16:32
'可以支持多个顶级物料，效率应该挺高，，，

Option Explicit

感谢大师出手！！！
我先试试您的解答，然后再反馈！

asdfasdf3546

参与                                 

大镁铝

楼主可以直接根据做了几辆自行车算成本了，太爽了