关于文件全路径名的拆分，我用API方法写了个函数供借鉴

lsdlyhz

Attribute VB_Name = "API_SplitPath_Unicode"
Option Private Module '如果希望在表格内显式调用，关闭该语句
Option Explicit

'将本文件导入你的VBA工程即可使用，如果您使用MS9.0运行时库，将"MSVCR100.DLL" 更改为"MSVCR90.DLL"
Declare PtrSafe Function Splitpath Lib "MSVCR100.DLL" Alias "_wsplitpath_s" (ByVal FullPath As LongPtr, _
                                                                        ByVal Drive As LongPtr, ByVal DriveSize As Long, _
                                                                        ByVal Dir As LongPtr, ByVal DirSize As Long, _
                                                                        ByVal Filename As LongPtr, ByVal FilenameSize As Long, _
                                                                        ByVal Ext As LongPtr, ByVal ExtSize As Long) As Long
'返回字符串中第一个vbNullChar字符以前的字符串，不包括vbNullChar本身
Public Function DelStrNull(ByVal retStr As String) As String
    Dim N As Integer
    N = InStr(1, retStr, vbNullChar)
    If (N >= 1) Then
        retStr = Left(retStr, N - 1)
    End If
    DelStrNull = retStr
End Function                                                                       
                                                                        
'Bz=0----返回 Ext
'Bz=1----返回 Fname
'Bz=2----返回 Dir
'Bz=3----返回 Drive
'Bz=4----返回 Fname+Ext
'Bz=5----返回 Drive+Dir
Function GetFilePart(ByVal FullPath As String, Optional Bz As Integer = 4) As String
    Dim sStr As String
    Dim sStr2 As String
    Dim Rt As Integer
    sStr = String(260, vbNullChar)
    If (Bz = 0) Then
        Rt = Splitpath(StrPtr(FullPath & vbNullChar), StrPtr(vbNullString), 0, StrPtr(vbNullString), 0, StrPtr(vbNullString), 0, StrPtr(sStr), 260)
    ElseIf (Bz = 1) Then
        Rt = Splitpath(StrPtr(FullPath & vbNullChar), StrPtr(vbNullString), 0, StrPtr(vbNullString), 0, StrPtr(sStr), 260, StrPtr(vbNullString), 0)
    ElseIf (Bz = 2) Then
        Rt = Splitpath(StrPtr(FullPath & vbNullChar), StrPtr(vbNullString), 0, StrPtr(sStr), 260, StrPtr(vbNullString), 0, StrPtr(vbNullString), 0)
    ElseIf (Bz = 3) Then
        Rt = Splitpath(StrPtr(FullPath & vbNullChar), StrPtr(sStr), 260, StrPtr(vbNullString), 0, StrPtr(vbNullString), 0, StrPtr(vbNullString), 0)
    ElseIf (Bz = 5) Then
        sStr2 = String(260, vbNullChar)
        Rt = Splitpath(StrPtr(FullPath & vbNullChar), StrPtr(sStr), 260, StrPtr(sStr2), 260, StrPtr(vbNullString), 0, StrPtr(vbNullString), 0)
    Else
        sStr2 = String(260, vbNullChar)
        Rt = Splitpath(StrPtr(FullPath & vbNullChar), StrPtr(vbNullString), 0, StrPtr(vbNullString), 0, StrPtr(sStr), 260, StrPtr(sStr2), 260)
    End If
    If (Bz > 3) Then
        GetFilePart = DelStrNull(sStr) + DelStrNull(sStr2)
    Else
        GetFilePart = DelStrNull(sStr)
    End If
End Function
-----------------------------
以上是导出的bas文件，将这个文件直接导入VBA工程就可以使用
我只在win64--VBA7.0下实验了。VBS7.0---Win32应该也可以

lsdlyhz

模块测试如下

-----------------
导出的Bas文件
API_SplitPath_Unicode.rar (872 Bytes, 下载次数: 47)

2014-12-15 07:20 上传

点击文件名下载附件

lsdlyhz

直接采用内存传递Excel的Unicode字符串的内存指针，
系统调用W版本的函数，直接填写这个内存，
躲过VBA参数转换、申请临时内存、两次U-A、A-U转换
唯一需要折腾的是VBA的BSTR字符存储机制

liulang0808

API不太了解。。。。
学习下

lsdlyhz

liulang0808 发表于 2014-12-15 07:36
API不太了解。。。。
学习下

单独要某个Part的话，我我这函数改写一下就可以了
比如你单独要扩展名，甚至你的VBA过程一下要处理四个Part，
你一次返回四个就可以了，
相应的位置象我这么传进去四个字符串地址，
------------
不过这样界面不能直接调用；
------------
建议大家在写所有复杂函数之前，一定先查查系统API
看看人家里面有没有对应的功能函数
再厉害咱自己写的代码都没系统内核的好

寒潮大冬瓜

lsdlyhz 发表于 2014-12-15 07:41
单独要某个Part的话，我我这函数改写一下就可以了
比如你单独要扩展名，甚至你的VBA过程一下要处理四个P ...

大侠你好！我在excel里怎么用？我期待的效果是在单元格内输入自定义函数→回车后提示输入路径或者选取包含路径的引用单元格→然后文件名就出现在公式输入的单元格里了，当然输入其他参数可以提取包含某特定字符的文件名或者某类后缀名的文件……感谢大侠指导！