有没有人试过如何把嵌入excel文件的flash提取出来？ - ExcelHome技术论坛

如题，我先是试着把文件另存为html文件。但是没有在对应的文件夹当中找到flash。

以下是引用井底之蛙在2007-4-29 17:37:54的发言：
发个附件让大家试试吧

以前随便写的代码(改了下可以提取word或excel文件里多个嵌入的FWS格式的flash文件,分别保存)

Sub ReadData()
Dim tmpFileName As String, FileNumber As Integer, OldName As String
Dim myFileId As Long
Dim myArr() As Byte
Dim i As Long
Dim MyFileLen As Long, myIndex As Long
Dim swfFileLen As Long
Dim swfArr() As Byte
tmpFileName = Application.GetOpenFilename("office File(*.doc;*.xls),*.doc;*.xls", , "确定要分析的office文件")
If tmpFileName = "False" Then Exit Sub
myFileId = FreeFile
Open tmpFileName For Binary As #myFileId
MyFileLen = LOF(myFileId)
ReDim myArr(MyFileLen - 1)
Get myFileId, , myArr()
Close myFileId
Application.ScreenUpdating = False
OldName = Left(tmpFileName, Len(tmpFileName) - 4)
i = 0
Do While i < MyFileLen
    If myArr(i) = &H46 Then
        If myArr(i + 1) = &H57 And myArr(i + 2) = &H53 Then
            swfFileLen = CLng(&H1000000) * myArr(i + 7) + CLng(&H10000) * myArr(i + 6) + CLng(&H100) * myArr(i + 5) + myArr(i + 4)
            ReDim swfArr(swfFileLen - 1)
            For myIndex = 0 To swfFileLen - 1
                swfArr(myIndex) = myArr(i + myIndex)
            Next myIndex
            myFileId = FreeFile
            tmpFileName = OldName & i & ".swf"
            Open tmpFileName For Binary As #myFileId
            Put #myFileId, , swfArr
            Close myFileId
            i = i + swfFileLen + 8
        Else
            i = i + 3
        End If
    Else
        i = i + 1
    End If
Loop
MsgBox "以" & OldName & "1-n.swf 名字保存"
End Sub

以下是引用lwxg在2007-4-29 21:49:07的发言：

以前随便写的代码(改了下可以提取word或excel文件里多个嵌入的FWS格式的flash文件,分别保存)

以下是引用鱼之乐在2007-4-29 18:28:44的发言：
从Word中提取Flash
1、需要一款16进制编辑工具WinHex
2、打开含有Flash的Word文档，点击“控件工具箱”的“设计模式”按钮进入设计模式，选择Word中的Flash，复制粘贴到任意文件夹，会看到一个“片段”文件。
3、打开WinHex，将该“片段”文件拉到WinHex中，单击下拉菜单“搜索”→“查找16进制值”，搜索“465753”，在搜索到的“465753”中的“4”位置上单击右键，选择“选块开始”。
4、继续“搜索”→“查找16进制值”，搜索“3A5C”，然后按住F3，直到出现“3A5C未找到”，点击“是”，在最后搜索到的“3A5C”中“C”位置上单击右键，选择“选块结尾”。（注：少数情况可能会搜索不到“3A5C”，则改为搜索“3A”或“5C”，方法相同）。
5、在选块内任意处点击右键→编辑→复制选块→进入新文件→输入文件名 (如test.swf) →保存。

以下是引用lwxg在2007-4-29 21:49:07的发言：

以前随便写的代码(改了下可以提取word或excel文件里多个嵌入的FWS格式的flash文件,分别保存)

仔细看了下具体数据,可以看到存在以下特征码,它的后面4个字节就是嵌入的SWF文件(似乎不管什么格式office嵌入之后就变FWS文件头),所以前面的代码应该也可以用于提取CWS的格式.