excel的表格里的一串内容分解出文字，数字，字母

象山海鲜

1. =LET(\a,MID($A$1,ROW($1:$99),1),CONCAT(REPT(\a,LENB(TEXT(\a,))=COLUMN(A1)-1)))

复制代码

右拉下拉

zpy2

select *,regexp2('[\p{Han}]+',f01) from 数据清洗数据源

635312245

象山海鲜 发表于 2024-5-18 12:40
右拉下拉

哇呀，太赞了

635312245

635312245 发表于 2024-5-20 16:11
哇呀，太赞了

=LET(\a,MID($A$1,ROW($1:$99),1),CONCAT(REPT(\a,LENB(TEXT(\a,))=COLUMN(A1)-1)))
太赞了

alan57

1. =LET(
   
2. _a, B2,
   
3. _b, "|",
   
4. _c, LEN(_a),
   
5. _d, MID(_a, SEQUENCE(, _c), 1),
   
6. _e, MAKEARRAY(1, _c, LAMBDA(r,c, IF(INDEX(_d, c) = ".", TRUE, ISNUMBER(VALUE(INDEX(_d, c)))))),
   
7. _e1, MAKEARRAY(1, _c, LAMBDA(r,c, CODE(INDEX(_d, c)) < 42000)),
   
8. _e2, MAKEARRAY(1, _c, LAMBDA(r,c, CODE(INDEX(_d, c)) < 130)),
   
9. _f1, MAKEARRAY(1, _c, LAMBDA(r,c, IF(c = 1, FALSE, XOR(INDEX(_e, c - 1), INDEX(_e, c))))),
   
10. _f2, MAKEARRAY(1, _c, LAMBDA(r,c, IF(c = 1, FALSE, XOR(INDEX(_e1, c - 1), INDEX(_e1, c))))),
    
11. _f3, MAKEARRAY(1, _c, LAMBDA(r,c, IF(c = 1, FALSE, XOR(INDEX(_e2, c - 1), INDEX(_e2, c))))),
    
12. _f, (_f1 + _f2 + _f3) > 0,
    
13. _g, MAKEARRAY(1, _c, LAMBDA(r,c, IF(INDEX(_f, c), _b & INDEX(_d, c), INDEX(_d, c)))),
    
14. _h, CONCAT(_g),
    
15. _i, TEXTSPLIT(_h, _b),
    
16. _i)

复制代码

我之前做了一个万能提取汉字字母数字的公式，仅供参考。

xxy1721

TEXTJOIN("",TRUE,TEXTSPLIT(C4,TEXTSPLIT(C4,CHAR(ROW($1:$57)),,TRUE),,TRUE))
TEXTJOIN("",TRUE,TEXTSPLIT(C4,TEXTSPLIT(C4,CHAR(ROW($65:$122)),,TRUE),,TRUE))
TEXTJOIN("",TRUE,TEXTSPLIT(C4,CHAR(ROW($48:$122)),,TRUE))

静听溪流

静听溪流

世界客都 发表于 2024-5-17 19:14
俊哥还没发布那个版本吧
目前大家有的都是内部发出来的少量安装包

office 365正则函数也出来了

世界客都

静听溪流 发表于 2024-5-21 21:04
office 365正则函数也出来了

谢谢贵哥，刚刚在群里看到了这个消息了

无关岁月

我也试试新函数

1. =DROP(REDUCE("",D2:D4,LAMBDA(_a,_b,VSTACK(_a,REGEXEXTRACT(_b,{"[一-龟]+","[A-Za-z]+","[0-9]+"})))),1)

复制代码